#!/usr/bin/perl -w

use strict;

my $filename = "";
my @leftside;
my @rightside;
my $rows = 0;
my $wasneg = 0;
my $waspos = 0;
my $neg_rows = 0;
my $pos_rows = 0;
my $leftline = 0;
my $rightline = 0;
my $str = "";
my $function = "";

while(<>) {
    chomp;
    s/\s+$//;
    s/\n+$//;
    s/\&/&amp;/g;
    s/\</&lt;/g;
    s/\>/&gt;/g;
    if (/^Index: (\w*\/?\w+\.?\w*)/) {
        my $diffrows = ( $neg_rows > $pos_rows ? $neg_rows : $pos_rows );
        if ($diffrows) {
            $rows = $rows + $diffrows;
        }
        $filename = $1;
    } elsif (/^===================================================================/) {
    } elsif (/^RCS file: /) {
    } elsif (/retrieving revision ([0-9.]+)/) {
    } elsif (/^diff/) {
    } elsif (/^--- ([\/\.\w_]+)\s+(\d+ \w+ \d+ [\d:]+ -?\d+\s*[\d.]*)/) {
        $leftside[$rows] = "</tbody></table></div></div>\n<div><a href=\"\" ".
                           "onclick=\"return toggleDiv($rows)\">+</a>".
                           "<div style=\"display: none\" id=\"div_label_$rows\"> $filename".
                           "<br/></div>\n".
                           "<div id=\"div_$rows\">\n<table width=\"100%\">\n<tbody>\n";
        $rightside[$rows] = "";
        $rows++;

        my $rev = defined($2) ? " $2" : "";
        $leftside[$rows] = "<tr><td class=\"fhead\" colspan=\"2\">"
                          ."<h4>File: $filename$rev</h4></td>\n";
        $neg_rows = 1;
    } elsif (/^\+\+\+ ([\/\.\w_]+)\s+(\d+ \w+ \d+ [\d:]+ -?\d+\s+[\d.]+)?/) {
        my $rev = defined($2) ? " $2" : "";
        $rightside[$rows] = "<td class=\"fhead\" colspan=\"2\">".
                            "<h4>File: $filename$rev</h4></td></tr>\n";
        $pos_rows = 1;
        $rows++;
    } elsif (/^@@ -(\d+),(\d+) \+(\d+),(\d+) @@ (\w+\.?\w*)\(/) {
        $leftline = $1;
        $rightline = $3;
        if ($5 ne $function) {
            $leftside[$rows] =
                "</tbody><tbody><tr><td class=\"ftoggle\" colspan=\"4\"><p><b>".
                "<a href=\"\" onclick=\"return toggleChunk($rows)\">$5</a></b></p>".
                "</td></tr></tbody>\n<tbody id=\"div_chunk_$rows\">\n";
        } else {
            $leftside[$rows] =
                "</tbody><tbody><tr><td class=\"toggle\" colspan=\"4\"><p><b>".
                "<a href=\"\" onclick=\"return toggleChunk($rows)\">...</a></b></p>".
                "</td></tr></tbody>\n<tbody id=\"div_chunk_$rows\">\n";
        }
        $function = $5;
        $rightside[$rows] = "";
        $rows++;
    } elsif (/^@@ -(\d+),(\d+) \+(\d+),(\d+) @@/) {
        $leftline = $1;
        $rightline = $3;
        $leftside[$rows] =
            "</tbody>\n<tbody><tr><td colspan=\"2\" class=\"lhead\"><p><b>".
            "<a href=\"\" onclick=\"return toggleChunk($rows)\">line $leftline".
            "</a></b></p></td>\n";
        $rightside[$rows] =
            "<td colspan=\"2\" class=\"lhead\"><b>line $rightline</b>".
            "</td></tr></tbody>\n<tbody id=\"div_chunk_$rows\">\n";
        $rows++;
    } elsif (/^-(.*)/) {
        $str = length($1) ? $1 : " ";
        $str =~ s/^\t/    /;
        $str = "<tr><td class=\"delnum\">$leftline</td><td class=\"del\">$str</td>\n";
        $leftside[$rows + $neg_rows] = $str;
        $leftline++;
        $neg_rows++;
    } elsif (/^\+(.*)/) {
        $str = length($1) ? $1 : " ";
        $str =~ s/^\t/    /;
        $str = "<td class=\"addnum\">$rightline</td><td class=\"add\">$str</td></tr>\n";
        $rightside[$rows + $pos_rows] = $str;
        $rightline++;
        $pos_rows++;
    } else {
        my $diffrows = ( $neg_rows > $pos_rows ? $neg_rows : $pos_rows );
        if ($diffrows) {
            $rows = $rows + $diffrows;
        }
        s/^\s//;
        s/^\t/    /;
        $str = $_;
        if (length($str) == 0) {
            $leftside[$rows] = "<tr><td class=\"samenum\">$leftline</td><td/>\n";
            $rightside[$rows] = "<td class=\"samenum\">$rightline</td><td/></tr>\n";
        } else {
            $leftside[$rows]  =
                "<tr><td class=\"same\">$leftline</td><td class=\"same\">$str</td>\n";
            $rightside[$rows] =
                "<td class=\"same\">$rightline</td><td class=\"same\">$str</td></tr>\n";
        }
        $leftline++;
        $rightline++;
        $rows++;
        $neg_rows = 0;
        $pos_rows = 0;
    }
}

print "<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Strict//EN\"
        \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd\">
<html>\n<head><title></title>\n";

print "
<style type=\"text/css\">
    table { white-space: pre; width: 100%; padding: 0; font-size: small }
    td { font-family: Lucida Console, monospace; padding: 0; border: none }
    th { background: black; color: white }
    td.ftoggle { background: #a0a0a0; text-align: center }
    td.toggle  { background: #e0e0e0; text-align: center }
    td.fhead   { background: #707070; text-align: center; width: 50% }
    td.lhead   { background: #808080; text-align: center }
    td.same    { background: #ffffff }
    td.samenum { background: #ffffff }
    td.add     { background: #ccffcc }
    td.addnum  { background: #ccffcc }
    td.del     { background: #ffcccc }
    td.delnum  { background: #ffcccc }
    td.diff    { background: #ffff99 }
    tbody      { padding: 0; border: none }
    tr         { padding: 0; border: none }
    tr.misc td {}
    tr.separator td {}
</style>

<script type=\"text/javascript\">
function toggleDiv(num) {
    var divname = \"div_\" + num;
    var divlbl  = \"div_label_\" + num;

    var element = document.getElementById(divname);
    var label = document.getElementById(divlbl);
    if (element.style.display == 'none') {
        element.style.display = 'inline';
        label.style.display = 'none';
    } else {
        element.style.display = 'none';
        label.style.display = 'inline';
    }

    return false;
}

function toggleChunk(num) {
    var divchunk = \"div_chunk_\" + num;
    var element = document.getElementById(divchunk);
    if (element.style.display == 'none') {
        element.style.display = '';
    } else {
        element.style.display = 'none';
    }

    return false;
}
</script></head>";

print "<body>\n<div><div><table><tbody><tr><td/></tr>\n";
LINELOOP: for (my $i = 0; $i < $rows; $i++) {
    if (!defined($leftside[$i]) && !defined($rightside[$i])) { next LINELOOP; }

    if (!defined($leftside[$i])) {
        $leftside[$i] = "<tr><td/><td/>\n";
    }
    if (!defined($rightside[$i])) {
        $rightside[$i] = "<td/><td/></tr>\n";
    }
    print "$leftside[$i]$rightside[$i]";
}
print "</tbody></table></div></div></body></html>";